記載されている会社名・製品名・システム名などは、各社の商標、または登録商標です。

Copyright (C) 2002 - 2021 SQUARE ENIX CO., LTD. All Rights Reserved.

FF11

5分で出来る!FF11のマクロ自動バックアップ設定方法

2021年10月16日

秋月螢雪

2017年11月、7年ぶりにFF11に復帰しました。 ヴァナ・ディールを再び冒険するためのゲーム内情報と、パソコンの選び方やコンフィグの設定方法などプレイ環境に関する情報を中心に記事を書いています。 Asura在住。3アカウント(Keisetsu/Kotoriko/Hozma)運用。 南国でFF11の20周年をお祝いすべく準備中です。 Twitterのフォローもお気軽に!

Tragedy comes suddenly

 

マクロ消失の悲劇とはコレでおさらば

マクロ消失の悲劇は、何の前触れもなく突然やってきます。

以前、注意喚起のつもりでバックアップ方法をいくつか紹介しましたが、手作業となるといつしかやらなくなるものです。

Crushed All Macros
【FF11】マクロや設定ファイルが壊れたときに備えた対処法

続きを見る

同じ悲劇を何度も繰り返さないよう、マクロ等ユーザデータを自動でバックアップする仕組みを作成しました。
この仕組みを導入することで、マクロ等が自動でバックアップされるようになります。

つまらない事故で、マクロ再作成に何日も費やすような無駄なことはもう終わりにしましょう。

 

FF11マクロのバックアップバッチ

バッチは、コマンドを記載した通りに実行させる指示書のようなものです。
FF11のマクロ等ユーザデータのバックアップに関する動作は、次のように定義しました。

  • 30世代までバックアップを取得し、31世代以降は削除する
  • 月1回、永久保存用のバックアップを取得する

無限にバックアップできるならそれに越したことはないのですが、ストレージは有限なので、実用的な範囲で残す世代を30世代としました。

 

FF11のマクロバックアップ自動化手順

用語や操作が難しく感じるかも知れませんが、記載した手順通りに作業すれば設定できます
タスクスケジューラを登録することで、バックアップを自動的に実行できるようになります。

バックアップフォルダの作成

パソコン「C:ドライブ」の直下に「FFXIBACKUP」フォルダを作成します。

Make Directory

 

拡張子の表示設定

フォルダの「表示」タブをクリックし、「ファイル名拡張子」にチェックを入れます。
※バッチファイルの配置に必要な設定です。

Show extension

 

バッチファイルの配置

作成したフォルダ「C:\FFXIBACKUP」に入り、右クリックから新規作成で「テキストドキュメント」を選択します。

「新しいテキスト ドキュメント.txt」を「ffxiconfig_backup.bat」に名称変更します。

次のポップアップが出た場合は、「はい(Y)」を押します。

「ffxiconfig_backup.bat」の空ファイルが作成されました。

「ffxiconfig_backup.bat」を右クリックし、「編集」を押します。

メモ帳が開きます。

 

次の内容をコピーし、メモ帳に貼り付けます。
(2021年10月19日 バッチの内容を簡素化しました。※処理内容に変更はありません。)

@echo off

rem =====FFXIユーザファイルの場所を指定する=====
set FFXIMCR="C:\Program Files (x86)\PlayOnline\SquareEnix\FINAL FANTASY XI\USER"

rem -----日付をYYYYMMDD形式にする-----
set yyyyMMdd=%date:/=%

rem 日付をYYYYMM形式にする
set YYYY=%date:~0,4%
set MM=%date:~5,2%

rem -----時間をHHMMSS形式にする-----
set hhmmss=%time:~0,8%
set hhmmss=%hhmmss::=%
set hhmmss=%hhmmss: =0%

rem =====バックアップ場所を指定する=====
set FFXIMCR_BK="C:\FFXIBACKUP\FFXIMCR_BK_%yyyyMMdd%_%hhmmss%"
set FFXIMCR_BKLOG="%FFXIMCR_BK%\backuplog.txt"

rem -----日付時間入りバックアップフォルダを作成する-----
mkdir %FFXIMCR_BK%

rem -----バックアップを実行する-----
robocopy %FFXIMCR% %FFXIMCR_BK% /MIR /LOG:%FFXIMCR_BKLOG% /R:3 /W:0 /NDL /FFT /NP

rem -----30世代以前のフォルダを削除する-----
set BKDIR="C:\FFXIBACKUP"
set count=30
for /f "skip=%count%" %%a in ('dir "%BKDIR%\FFXIMCR_BK_*" /B /O-N /AD') do (
rmdir /S /Q %BKDIR%\%%a
)

rem -----完了メッセージを表示する-----
echo "Daily Backup Complete"

rem -----月次バックアップを取得する-----
@rem 月次バックアップ用フォルダを指定する
set MONTH_BK="C:\FFXIBACKUP\MONTH\%YYYY%%MM%"
set MONTH_BKLOG="%MONTH_BK%\backuplog.txt"

@rem 当月の月次バックアップフォルダが存在するかチェックする
if exist %MONTH_BK% goto CODE1
if not exist %MONTH_BK% goto CODE2

@rem ディレクトリが存在する場合、何もしない
:CODE1
echo "Monthly Backup has already existed"
exit /b

@rem ディレクトリが存在しない場合
:CODE2
echo "Monthly Backup Began"
@rem -----日付入りバックアップフォルダを作成する-----
mkdir %MONTH_BK%
@rem -----月次バックアップを実行する-----
robocopy %FFXIMCR% %MONTH_BK% /MIR /LOG:%MONTH_BKLOG% /R:3 /W:0 /NDL /FFT /NP
echo "Monthly Backup Complete"


保存します。

 

バッチファイルの動作テスト

保存したバッチファイルをダブルクリックし、実行します。

コマンドプロンプトが立ち上がり、バックアップ処理が実行されることを確認します。

「C:\FFXIBACKUP」フォルダの中に、「FFXIMCR_BK_YYYYMMDD_hhmmss(西暦年月日・時分秒)」のフォルダと「MONTH」フォルダが作成されることを確認します。

それぞれのフォルダの中にFF11のマクロ等ユーザデータがバックアップされたことを確認します。

 

タスクスケジューラに登録して自動バックアップ

Windowsのスタートメニューから「Windows 管理ツール」を開き、「タスク スケジューラ」を起動します。

「タスクの作成」をクリックします。

タスク作成用のウィンドウが開きます。全般タブの「名前(M):」に「ffxiconfig_backup」と入力します。

トリガータブを選択し、「新規(N)...」をクリックします。

タスクの開始(G): は「ログオン時」を選択します。設定を「特定のユーザー(C):」に変更します。

※パソコンを立ち上げっぱなしで使っている人などは、曜日や時間など、ご自身の環境に合わせてトリガーを変更してください。

トリガー「ログオン時」、詳細「ユーザ 〇〇 のログオン時」が作成されたことを確認します。

操作タブを選択し、「新規(N)...」をクリックします。

「参照(R)...」をクリックします。

作成したバッチファイル「ffxiconfig_backup.bat」を選択し「開く(O)」をクリックします。

プログラム/スクリプトにバッチファイルのパスが入力されたことを確認し、「OK」をクリックします。

条件タブを選択し「電源」のチェックボックスを外し、「OK」をクリックします。

作成したタスク「ffxiconfig_backup」が登録されたことを確認します。

 

タスクスケジューラの動作テスト

パソコンを再起動しログオンします。
「C:\FFXIBACKUP」フォルダの下に、新しいバックアップフォルダが作成されたことを確認します。

ここまで設定したら、Windowsへのログオン時にバックアップバッチが実行され、バックアップが取得されます。
30世代まで保存され、古いバックアップから削除されます。

 

マクロ等の復元方法

バックアップしたマクロ等ユーザファイルの復元は簡単です。
取得元を一旦削除し、バックアップしたフォルダをコピーすれば完了です。

オプションを変更せずにインストールしているなら、次の場所です。

C:\Program Files (x86)\PlayOnline\SquareEnix\FINAL FANTASY XI\USER

貼り付けには管理者権限が必要になる旨のポップアップが出た場合は「続行(C)」を押します。

元のフォルダに貼り付けたら、復元完了です。

 

まとめ

FF11はマクロが命と言っても過言ではないゲームであるにも関わらず、マクロ保全の仕組みは不十分です。
開発陣にこそ認識して頂きたいものですが、現状は予算も限られているので難しいのでしょう。

バックアップバッチとタスクスケジューラの登録で、ログオン時にFF11にとって超重要なマクロ等ユーザファイルを自動で保存できるようになります。

手順通りに作業すれば5分程度で出来ますので、ものぐさな人ほど、この重要な作業を実施してみてください。
マクロ消失時にかかる労力に比べたら、瞬です。

バッチ作成にあたり、ご協力頂いたNarciela@Bismarck さん、萩原子荻@お仕事忙しくなりそう勢さん、この場を借りて御礼申し上げます。

 

以上、5分で出来る!FF11のマクロ自動バックアップ設定方法 でした。

  • この記事を書いた人

秋月螢雪

2017年11月、7年ぶりにFF11に復帰しました。 ヴァナ・ディールを再び冒険するためのゲーム内情報と、パソコンの選び方やコンフィグの設定方法などプレイ環境に関する情報を中心に記事を書いています。 Asura在住。3アカウント(Keisetsu/Kotoriko/Hozma)運用。 南国でFF11の20周年をお祝いすべく準備中です。 Twitterのフォローもお気軽に!

-FF11
-, ,